Print Page - is this complicated ?

Programming => Example Code => Topic started by: Peter on December 24, 2010, 05:03:39 AM

Title: is this complicated ?
Post by: Peter on December 24, 2010, 05:03:39 AM

Hi Charles,

some new commands:

createImage()
copyImageRect()
ClearImage()
FreeImage()

look at the demo to see what it means.
Peter

'DEMO'

Code: [Select]

IndexBase 0
Include Once "Win_C.inc"  'Constants
Include Once "Win_D.inc"  'Declarations
Include Once "Win_G.inc"  'Graphics 

Function WndProc(byval hWnd as long,byval wMsg as long, byval wParam as long,byval lparam as long) as long callback
if wMsg = WM_CREATE
'
elseif wMsg = WM_PAINT
'
elseif wMsg = WM_MOUSEMOVE
xMouse = LoWord(lParam)
yMouse = HiWord(lParam)
'
elseif wMsg = WM_DESTROY
PostQuitMessage 0
else
Function = DefWindowProc hWnd,wMsg,wParam,lParam
endif
End Function

/* DECLARATIONS  */

/* VARIABLES  */
Dim hwnd, sx, iHdc,hFont as long
Dim s as string
s = "MERRY CHRISTMAS"
hwnd = SetWindow "OxygenBasic",500,400,WS_DLGFRAME
bHdc = SetBuffer WinWidth, WinHeight
iHdc = CreateImage 1000,400                   
hFont = CreateFont (128,20,0,0,FW_BOLD,0,0,0,0,0,0,0,0,"times")
SelectObject iHdc,hFont
SetBkMode iHdc,1
SetTextcolor iHdc,RGB(0,255,0)
Randomize


/*  MAINLOOP  */
While EscKey() =0
ClearImage iHdc,1000,400                '<-- DContex, ImageWidth, ImageHeight
SetTextcolor iHdc,RGB(255,155,255)
TextOut iHdc,500,100,s,Len(s)
CopyImageRect iHdc,sx,0,500,400,0,0    '<-- DContex, xImage, yImage, ImageWidth, ImageHeight, xBuffer, yBuffer
sx +=1                                   
if sx =980 then sx =0
DoEvents
FlipBuffer
'Sleep 10
Wend
FreeBuffer
FreeImages
ExitProcess 0     

/* FUNCTIONS  */

Title: Re: is this complicated ?
Post by: kryton9 on December 24, 2010, 12:31:47 PM

I couldn't find the demo in the rar file Peter.

Also, I noticed a User Defined Type of TRGB. Wouldn't it be better to make a class of that type, this way we can have overloaded methods to handle different types, long, float... or can we override even when UDT's?

Edited:Oh I see the demo is the source code above in the previous post :)

Title: Re: is this complicated ?
Post by: Peter on December 24, 2010, 12:59:22 PM

Hi Kryton9,

if you like a class, make your class.
is open source!

Merry Christmas!

Peter

Title: Re: is this complicated ?
Post by: kryton9 on December 24, 2010, 01:06:06 PM

Thanks Peter, Merry Christmas to you too. I am enjoying studying your code as well as new oxygen alpha.

Title: Re: is this complicated ?
Post by: Peter on December 24, 2010, 03:41:05 PM

Here is another demo for you!

Code: [Select]

IndexBase 0
Include Once "Win_C.inc"  'Constants
Include Once "Win_D.inc"  'Declarations
Include Once "Win_G.inc"  'Graphics 

Function WndProc(byval hWnd as long,byval wMsg as long, byval wParam as long,byval lparam as long) as long callback
if wMsg = WM_CREATE
'
elseif wMsg = WM_PAINT
'
elseif wMsg = WM_MOUSEMOVE
xMouse = LoWord(lParam)
yMouse = HiWord(lParam)
InValidateRect hwnd,0,0
'
elseif wMsg = WM_DESTROY
PostQuitMessage 0
else
Function = DefWindowProc hWnd,wMsg,wParam,lParam
endif
End Function

/* DECLARATIONS  */

/* VARIABLES  */
Dim hwnd, sa, sx, iHdc, hFont as long
Dim s as string
s = "HAPPY NEW YEAR"
hwnd = SetWindow "OxygenBasic o24",500,400,WS_DLGFRAME
bHdc = SetBuffer WinWidth, WinHeight
iHdc = CreateImage 1000,400                   
hFont = CreateFont (160,22,0,0,FW_BOLD,0,0,0,0,0,0,0,0,"times")
SelectObject iHdc,hFont
SetBkMode iHdc,1
SetTextcolor iHdc,RGB(0,255,0)
Randomize
SetTextcolor iHdc,RGB(255,155,55)
TextOut iHdc,500,100,s,Len(s)

/*  MAINLOOP  */
While EscKey() =0
ClearBuffer()               
CopyImageRect iHdc,sx,0,500,400,0,0    
For sa=1 To 50
Circle,bHdc,Rand(1,499),Rand(1,399),Rand(8,48),Rand(Rgb(64,64,64),Rgb(255,255,255))
Next
sx +=2                                   
if sx >=990 then sx =0
DoEvents
FlipBuffer()
'Sleep 10
Wend
FreeBuffer()
FreeImages()
ExitProcess 0     

/* FUNCTIONS  */

Title: Re: is this complicated ?
Post by: kryton9 on December 25, 2010, 12:47:34 AM

Another nice one, thanks.

Title: Re: is this complicated ?
Post by: Charles Pegge on December 25, 2010, 02:43:08 AM

Thanks Peter,

I will explore the possibilities of even simpler code :)

(I have a little time before serious feasting begins!)

Charles

Title: Re: is this complicated ?
Post by: Charles Pegge on December 25, 2010, 04:41:07 AM

Hiding the windows infrastructure:

Win_F.inc

Code: [Select]

IndexBase 0
Include Once "Win_C.inc"  'Constants
Include Once "Win_D.inc"  'Declarations
Include Once "Win_G.inc"  'Graphics 

Function WndProc(byval hWnd as long,byval wMsg as long, byval wParam as long,byval lparam as long) as long callback
if wMsg = WM_CREATE
'
elseif wMsg = WM_PAINT
'
elseif wMsg = WM_MOUSEMOVE
xMouse = LoWord(lParam)
yMouse = HiWord(lParam)
InValidateRect hwnd,0,0
'
elseif wMsg = WM_DESTROY
PostQuitMessage 0
else
Function = DefWindowProc hWnd,wMsg,wParam,lParam
endif
End Function


'============

create 'invoke macro

'============



/*  MAINLOOP  */

While EscKey() =0

ClearBuffer()               

'=========

run 'invoke macro

'=========

DoEvents
FlipBuffer()
Sleep 5
Wend
FreeBuffer()
FreeImages()
ExitProcess 0

Demo

Code: [Select]


'=========
def create
'=========

/* DECLARATIONS  */

/* VARIABLES  */

Dim hwnd, sa, sx, iHdc, hFont as long
Dim s as string
s = "HAPPY NEW YEAR"
hwnd = SetWindow "OxygenBasic o24",500,400,WS_DLGFRAME
bHdc = SetBuffer WinWidth, WinHeight
iHdc = CreateImage 1000,400                   
hFont = CreateFont (160,22,0,0,FW_BOLD,0,0,0,0,0,0,0,0,"times")
SelectObject iHdc,hFont
SetBkMode iHdc,1
SetTextcolor iHdc,RGB(0,255,0)
Randomize
SetTextcolor iHdc,RGB(255,155,55)
TextOut iHdc,500,100,s,Len(s)

type vector4i sys a,b,c,d
vector4i circ[50]
For sa=0 to 49
  circ[sa].a=Rand(1,499)
  circ[sa].b=Rand(1,399)
  circ[sa].c=Rand(8,48)
  circ [sa].d=Rand(Rgb(64,64,64),Rgb(255,255,255))
Next

/* FUNCTIONS  */

end def 'create


'======
def run
'======

CopyImageRect iHdc,sx,0,500,400,0,0    
sx +=2 : if sx >=990 then sx =0
'
For sa=0 To 49
  Circle,bHdc,circ[sa].a,circ[sa].b,circ[sa].c,circ[sa].d
  c=circ[sa].c
  if c>=48 then circ[sa].a=Rand(1,499) : circ[sa].b=Rand(1,399) : c=8
  circ[sa].c=c+1  
Next

end def

include "Win_F.inc"

Title: Re: is this complicated ?
Post by: Peter on December 25, 2010, 06:43:36 AM

thanks Charles,

Def is great!

Question: (vector4i circ[50]) is (circ[50] as vector4i ?)

what type has sys ?
and what are variables without any type?

Sleep under 10 msec has no effect!
what we need is a command like LimitFrame(). QueryPerformanceCounter would be good for it!

Peter

and here something for the users brains.

Code: [Select]

IndexBase 0

Include Once "Win_C.inc"  
Include Once "Win_D.inc"  
Include Once "Win_G.inc"   

Function WndProc(byval hWnd as long,byval wMsg as long, byval wParam as long,byval lparam as long) as long callback
if wMsg = WM_CREATE
'
elseif wMsg = WM_PAINT
'
elseif wMsg = WM_MOUSEMOVE
xMouse = LoWord(lParam)
yMouse = HiWord(lParam)
InValidateRect hwnd,0,0
'
elseif wMsg = WM_DESTROY
PostQuitMessage 0
else
Function = DefWindowProc hWnd,wMsg,wParam,lParam
endif
End Function

Declare Function LoadPicture(byval pfile as string) as long
Declare Function DrawToImage(byval PicHdc As Long, byval x1 As Long, byval y1 As Long, byval w as long, byval h as long)
Declare Function FreePicture()

Dim jc,bHdc,iHdc,dir,pHnd(10),pHdc(10) as long
Dim s1,s2,s3,s4,s5,s6,s7,s8 as long

SetWindow "HappyShow 2010",320,264,WS_DLGFRAME
bHdc = SetBuffer WinWidth,WinHeight
iHdc = CreateImage 2560,264

s1 = LoadPicture "pics/christball320x240.bmp"
s2 = LoadPicture "pics/snowman320x240.bmp"
s3 = LoadPicture "pics/wintersnow320x240.bmp"
s4 = LoadPicture "pics/christmas320x240.bmp"
s5 = LoadPicture "pics/tannen320x240.bmp"
s6 = LoadPicture "pics/newtree320x240.bmp"
s7 = LoadPicture "pics/morewinter320x240.bmp"
s8 = LoadPicture "pics/happy320x240.bmp"

DrawToImage s1,0,0,320,240 
DrawToImage s2,320,0,320,240 
DrawToImage s3,640,0,320,240 
DrawToImage s4,960,0,320,240 
DrawToImage s5,1280,0,320,240 
DrawToImage s6,1600,0,320,240 
DrawToImage s7,1920,0,320,240 
DrawToImage s8,2240,0,320,240 

While EscKey() =0
CopyImageRect iHdc,jc,0,320,240,0,0 
if dir =0 
jc = jc +2
if jc >=2240 Then dir =1 
elseif dir =1
jc = jc -2
if jc <=0 Then dir =0 
endif
DoEvents
FlipBuffer
Sleep 10
Wend
FreeBuffer
FreeImages
FreePicture
ExitProcess 0

Function LoadPicture(byval pfile as string) as long
static co as long
co += 1
pHnd(co) = LoadImage(0, pfile, 0, 0, 0, 16)
pHdc(co) = CreateCompatibleDC(hdc)
SelectObject pHdc(co), pHnd(co)               
Function = pHdc(co)
End Function

Function FreePicture()
For c=1 To 8
DeleteObject pHnd(c): DeleteDC pHdc(c)
Next
End Function

Function DrawToImage(byval PicHdc As Long,byval x1 As Long, byval y1 As Long, byval w as long, byval h as long)
BitBlt iHdc, x1, y1, w, h, PicHdc, 0, 0, &hCC0020
End Function

[attachment deleted by admin]

Title: Re: is this complicated ?
Post by: Charles Pegge on December 25, 2010, 12:06:22 PM

Thanks Peter,

when the type of a variable is unspecified it defaults to sys

sys is long for 32 bit systems and will be quad for 64 bit systems.

type vector4i sys a,b,c,d
is very naughty but useful for simple structures 8)

These are all equivalent:

vector4i circ[50]
dim vector4i circ[50]
dim as vector4i circ[50]
dim circ[50] as vector4i
dim byval circ[50] as vector4i
var vector4i circ[50]

Round brackets are also allowed except for the first one. (c syntax)

Sleep <10 gives the CPU core the opportunity to do tasks between loops even though it is below the resolution of the windows message timer.

Charles

Title: Re: is this complicated ?
Post by: Peter on December 25, 2010, 12:59:22 PM

thank you for your explanation Charles.

I like square brackets much more than round brackets.

And here:
I found this at Aurel Basic. I have modified it a bit.
to be honest, something more !

This isn't declared yet '% WS_MINIMIZEBOX = &H20000'
Write it in the source code or remove it.
Peter

Code: [Select]

IndexBase 0
Include Once "Win_C.inc"  'Constants
Include Once "Win_D.inc"  'Declarations
Include Once "Win_G.inc"  'Graphics 

Function WndProc(byval hWnd as long,byval wMsg as long, byval wParam as long,byval lparam as long) as long callback
if wMsg = WM_CREATE
'
elseif wMsg = WM_PAINT
'
elseif wMsg = WM_MOUSEMOVE
xMouse = LoWord(lParam)
yMouse = HiWord(lParam)
'
elseif wMsg = WM_DESTROY
PostQuitMessage 0
else
Function = DefWindowProc hWnd,wMsg,wParam,lParam
endif
End Function

Dim pi, v, v3, v4, x, y, x2, y2, x3, y3, x4, y4, x5, y5, n, p as single 
Dim s, bHdc, hFont as long 
pi = 3.14159

SetWindow "Rotate...", 640, 500, WS_MINIMIZEBOX | WS_OVERLAPPED  
bHdc = SetBuffer 640,500 
hFont = CreateFont (32,20,0,0,FW_BOLD,0,0,0,0,0,0,0,0,"times")
SelectObject bHdc,hFont
SetBkMode bHdc,1

While (WinExit =0) & (EscKey()=0) 
ClearBuffer()
SetTextColor bHdc,Rgb(200, 240, 0)
TextOut bHdc,90,0,"YOU NEEDN'T WAIT!",17
For v =0 To 7 
v = v + 0.008
if v = 6.28 Then v=0
v3 = v3 + .003
v4 = v4 + .01
if v3 >= 6.28 Then v3 = 0.003
if v4 >= 6.28 Then v4 = 0.01

x =  Cos(v3) * 180 + (Cos(v) * -20 + 320)
y =  Sin(v3) * 180 + (Sin(v) * -20 + 240)
x2 = Cos(v3) * 180 + (Cos(v) *  20 + 320)
y2 = Sin(v3) * 180 + (Sin(v) *  20 + 240)
x3 = Cos(v3) * 180 + (Cos(v) *   0 + 320)
y3 = Sin(v3) * 180 + (Sin(v) *   0 + 240)

x4 = Cos(v)  * 20  + 320
y4 = Sin(v)  * 20  + 240
x5 = Cos(v4) * 80  + 320
y5 = Sin(v4) * 80  + 240

Circle bHdc, x3, y3, 20, Rgb(100, 200, 255)
Circle bHdc, x4, y4, 40, Rgb(22,  220, 100)
Circle bHdc, x5, y5, 10, Rgb(255, 120,  50)
Next
DoEvents
FlipBuffer
Sleep 24
Wend
Beep 440,400
FreeBuffer()
ExitProcess 0

Title: Re: is this complicated ?
Post by: Aurel on August 21, 2012, 02:25:42 AM

I would like to ask about Macro.
What is the main advantage of using MACRO ?
Is it posible to use macro to hide WndProc ?

Title: Re: is this complicated ?
Post by: Charles Pegge on August 21, 2012, 03:16:35 AM

Hi Aurel,

I use short macros in projectsA/openglGUI/viewer.o2bas to hide most of the program, including wndproc, and to expose selected parts of the program. This is a seriously complex piece of programming. It is my most sensitive 'canary' for OxygenBasic. :) I did a fair amount of work on this system a few days ago, and this is how the top level appears now:

Code: OxygenBasic

 
 
  ' GL Example using Glo2/openglview sourcelibrary
  '
  ' 10 Sept 2010
  ' 14 Sept 2011
  ' 07 May  2012
  ' 14 Aug  2012
  '
  ' Charles Pegge
 
 
  '==============
  'SPECIFICATIONS
  '==============
 
 
  $ WindowTitle  "OxygenBasic Opengl Viewer Demo"
  $ WindowSize   800,800
 
 
  'Controls
  '--------
  
  $ NavigationKeys
  $ FunctionKeys
  $ GraphicalControls
 
  'sources for editbox
 
  $ textfile1 "portviewer2Man.txt"
 
 
  'color / images / textures
  '-------------------------
 
  $ BackColor 0.3,0,.1,0
  $ GDIplus
  '$ BackImage "../../examples/images/dawn1815.jpg"
 
 
  'standard lighting
  '-----------------
 
  $ LightPosition 0.0, 8.0, 8.0, 1.0
  $ LightAmbient  1.0, 1.0, 1.0, 1.0
  $ LightDiffuse  1.0, 1.0, 1.0, 1.0 
  $ LightSpecular 1.0, 1.0, 1.0, 1.0
 
 
  'standard material
  '-----------------
 
  $ MaterialAmbient   .15, .15, 0.2, 1.0
  $ MaterialDiffuse   0.7, 0.7, 0.6, 1.0
  $ MaterialSpecular  0.0, 0.0, 0.1, 1.0
  $ MaterialShininess 0
 
  $ Geometries   include "geometries.inc"
  $ DrawingLists include "DrawingLists.inc"
  $ scenes       include "scenes.inc"
  $ StartScene   7
 
  $ fontA "Arial",FW_SEMIBOLD
  $ fontB "Lucida Console",FW_BOLD
  '$ fontC "Times",FW_NORMAL
 
 
 
  'COMPILING TO OXYGEN-DEPENDENT EXECUTABLE
  '----------------------------------------
 
  '#file "Viewer.exe"
 
  'COMPILING TO INDEPENDENT EXECUTABLE
 
  $ FileName "Viewer.exe"
  'include "..\..\inc\RTL64.inc" 'to compile 64bit
  'include "..\..\inc\RTL32.inc" 'to compile 32bit
 
 
 
  '===========
  'MAIN SOURCE
  '===========
 
  include "OpenglView.inc"
 

The intention is to bring together in one place, all the parts of the system which are of interest to the user, without making the system inefficient or bloated.

Charles

Title: Re: is this complicated ?
Post by: Aurel on August 21, 2012, 03:34:51 AM

Hi Charles

I agree with you that this is a complex piece of programming.
In first place i ask because i need to know what is a main difference between macro
and function.
I refer to this simple example given by Peter:

Code: [Select]

Macro Rebirth
   Stars[i].yStar = Rand(1, yRes - 2)
   Stars[i].speed = Rand(1, 20) * 0.1 + 1
End Macro

And then is used inside standard Function.
Is macro some sort of static function with global scope ?
THen i see that macro can have parameters.
I was wondering is there a way to define or declare variable as function(pointer)
which can be called globaly?

I will try to do some more test that i have better perception what is what,,ufff...

Aurel

Title: Re: is this complicated ?
Post by: Charles Pegge on August 21, 2012, 05:25:05 AM

You can often substitute macros for functions and vice-versa. The scoping rules are different however. The macro will see all the variables in the environment from where it is invoked, including locals and statics. Macros will always be faster than functions, but the more complex ones will use more code when they are used several times.

Macros work only by symbol substitution. Code is expanded and inserted to replace the invoking expression. There are no calls involved. They go back to the earliest days of computing when computers used valves :)

Hiword and Loword are very good candidates for macros:

macro loword(a)
a and 0xffff
end macro

macro hiword(a)
a>>16
end macro

Charles

Title: Re: is this complicated ?
Post by: Peter on August 21, 2012, 05:50:52 AM

Code: [Select]

Macro LoWord(a)
a & 0xFFFF    'Low part
End Macro

Macro HiWord(a)
a>>16           'High part
End Macro 

a=0xFFFF0064

print HiWord(a)  '65535
print LoWord(a)  '100

'&' is a bit better because
'AND' is logic, not a bit operation in BASIC!

Title: Re: is this complicated ?
Post by: Charles Pegge on August 21, 2012, 07:42:28 AM

Hi Peter,

OxygenBasic conflates bitwise and logical operators. Both forms translate to something like:

mov eax,a
and eax,0xffff

Charles

Title: Re: is this complicated ?
Post by: Aurel on October 19, 2012, 12:58:34 PM

Well i do not know nothing about def
and i just see first time that def contain whole block of code ???
I really think that is time Charles that you explain or create help file
with closer explanation what is and how to use :
macro and def and some other things...
do you agree...?

Oxygen Basic

Programming => Example Code => Topic started by: Peter on December 24, 2010, 05:03:39 AM