Author Topic: SBT (Read 35397 times)

Charles Pegge · « **Reply #90 on:** May 16, 2015, 01:17:47 PM »

In general, the OS expects to see only one GUI per process, ie: one message loop and one main window.

JRS · « **Reply #91 on:** May 16, 2015, 01:24:34 PM »

Seems to be the case. I took a look at the DLLC code to see how you solved the mystery and the ASM magic ended the show for me.

Quote from: IUP Mailing List

Note that in GTK this is really easy to achieve: GLib is thread-safe,
and so you can simply call g_idle_add from your worker thread to
register an idle callback. The idle callback will then be called from
the GTK main loop in the IUP thread (since IUP simply uses the GTK main
loop, all this should work seamlessly without any modification to IUP).

.

JRS · « **Reply #92 on:** May 17, 2015, 05:55:50 PM »

Hi Charles,

I was able to get the thread execution object handle and pass it back to the host. I can now access thread variables and call functions just like the embedded interface I started off with.

Check out All BASIC for more.

John

JRS · « **Reply #93 on:** May 18, 2015, 08:32:42 AM »

Charles,

Now that I'm able to call SB thread script functions from the host (boot) SB script, can I follow your path and wrap the IUP GUI generation and event code into a SB main::main function? How would you suggest I precede from here to test if your DLLC method and see if I can get it working under Linux?

Update

I got both IUP test window to show. I needed to give the thread scripts time to load before calling their main functions. The problem is the event buffers fill up quickly and puts the windows in distress. All I need to figure out now is to how to drain and process the events.

Here is what gets returned from the thread main function.

Code: Script BASIC

Iup::Show(Form)
main=Iup::MainLoop()
END FUNCTION
 

Code: Script BASIC

IMPORT sbt.inc
 
sb1 = SB_ThreadStart("test.sbq",undef,"/etc/scriba/basic.conf")
sb2 = SB_ThreadStart("test2.sbq",undef,"/etc/scriba/basic.conf")
sb1_rtn = SB_CallSubArgs(sb1, "main::main", sb1, 0)
sb2_rtn = SB_CallSubArgs(sb2, "main::main", sb2, 0)
 
PRINT "Thread 1 = ", sb1_rtn,"\n"
PRINT "Thread 2 = ", sb2_rtn,"\n"
 
LINE INPUT wait
 

jrs@laptop:~/sb/sb22/sbt$ scriba iupmain.sb Thread 1 = undef Thread 2 = undef Killed jrs@laptop:~/sb/sb22/sbt$

I think I'm close to getting this working. I'm just confused how to process events. Can you offer any advice?

JRS · « **Reply #94 on:** May 19, 2015, 04:49:48 PM »

Hi Charles,

Code: OxygenBasic

  sbcb[v]={pProg,fa,np, @t.scriba_CallArgEx,RetVal,idat} 'PROGRAM,FUNCTION
  r=CallBackTable[v] 'callback handle to pass on to the DLL
  *pReturnValue=ReturnLong pst,r
 

If I can work my way through this O2 functionality, I think I can finish up from there. I'm trying to imagine this in C.

Charles Pegge · « **Reply #95 on:** May 19, 2015, 05:34:41 PM »

Hi John,

I would suggest processing IUP low level callback messages, like mouse-move, without attempting to pass the callback to SB. Mouse coordinates and key states can be stored in SB global variables, or a shared table, leaving more occasional events, like button-clicks to be relayed onto SB callbacks.

As you can see, threading and callbacks is really messy stuff, and way beyond the scope of a casual SB user. So the more the extension module can do internally, the better.

DLLC was too generic to be useable for this task.

JRS · « **Reply #96 on:** May 19, 2015, 05:56:21 PM »

Quote from: Charles

I would suggest processing IUP low level callback messages, like mouse-move, without attempting to pass the callback to SB.

I do that now with the SB IUP extension module. It's a bit of a hack as I'm returning to SB with every filtered callback and SB does the ICALL. This goes back to my inability to get MyICall (trial ext. mod.) to work. I'm by that now.

I still need to get square in my head how thread functions really don't return but remain as a life of their own in the same parent process. It's like playing who's on first. It still boggles my mind that a complete working scriba is created as a threaded function. I've decided to use MT as the thread cop. Trying to use sleep while things get loaded is too variable. (program size, ext. mod, ...) MT will smooth that out.

I have to move the event routines out of the IUP extension module and into the SBT ext. mod. My hope is this direction of fooling the threads as to who is in control is a slick trick or the method I posted from the IUP mailing list is the proper method to chose. I want something cross platform and you have already paved the way.

One of the next SB tasks on my list is to be able from one called SB extension module function call another without returning to SB.

JRS · « **Reply #97 on:** May 19, 2015, 11:08:00 PM »

Charles,

Before I start on a considerable effort to reproduce what you have done in DLLC, I'm going to try the call g_idle_add from the worker thread to
register an idle callback method first before trying to implant into SBT the IUP event responsibilities.

This single thread example works using my existing IUP custom Iup::MainLoop (single step callback return to SB) It looks like the only issue is treating the Gtk MainLoop() with a does of g_idle_add to play nicely with threads.

Notice MT's first day on the job as a thread cop. Works great and responsive.

Code: Script BASIC

IMPORT mt.bas
IMPORT sbt.inc
 
sb1 = SB_ThreadStart("test.sbq",undef,"/etc/scriba/basic.conf")
 
WHILE mt::GetVariable("STATUS") <> "OK"
WEND
 
sb1_rtn = SB_CallSubArgs(sb1, "main::main", sb1, 0)
 
SB_Destroy(sb1)

test.sbq

Code: Script BASIC

' Script BASIC Rapid-Q form conversion
 
IMPORT mt.bas
IMPORT sbt.inc
IMPORT iup.bas
 
' CALLBACKS FUNCTIONS
 
SUB Button_Quit
  Iup::ExitLoop = TRUE
END SUB  
 
SUB Win_exit
  Iup::ExitLoop = TRUE
END SUB
 
FUNCTION main(pProg,idat)
  
  ' SBIUP-Q INIT
  
  Iup::Open()
  Iup::SetGlobal("DEFAULTFONT", "Sans, 7.5")
  
  ' CREATE FORM
  
  Form = Iup::Create("dialog")
         Iup::SetAttributes(Form, "RASTERSIZE=320x240, TITLE=\"Form1\"")
  
       Label1  = Iup::Create("label")
                 Iup::SetAttributes(Label1, "TITLE=\"Customer\", RASTERSIZE=55x13, FLOATING=YES, POSITION=\"19,19\"")
  
       Edit1   = Iup::Create("text")
                 Iup::SetAttributes(Edit1, "RASTERSIZE=121x21, FLOATING=YES, POSITION=\"72,16\"")
  
       Button1 = Iup::Create("button")
                 Iup::SetAttributes(Button1, "TITLE=\"&Quit\", RASTERSIZE=75x25, FLOATING=YES, POSITION=\"107,164\"")
  
  vbx = Iup::Vbox(Label1, Edit1, Button1)
  Iup::Append(Form, vbx)
                 
  ' SET CALLBACKS
  
  Iup::SetCallback(Form, "CLOSE_CB", ADDRESS(Win_exit()))
  Iup::SetCallback(Button1, "ACTION", ADDRESS(Button_Quit()))
  
  ' MAIN
  
  ' Iup::Show(Iup::LayoutDialog(Form))
  Iup::Show(Form)
  Iup::MainLoop
  Iup::Close
  main = "STARTED"
END FUNCTION
mt::SetVariable("STATUS","OK")
 

.

JRS · « **Reply #98 on:** May 20, 2015, 09:30:34 AM »

Charles,

I think I'm on my way to to actually getting this working. I added a new SB_msSleep() function to give me better control of my waiting for thread status MT messages.

Code: Script BASIC

WHILE mt::GetVariable("STATUS") <> "OK"
  SB_msSleep(20)
WEND
 

This does a 20 microseconds Linux usleep call.

The plan going forward is to create a common IUP callback that handles all of the various callback function argument lists as a variadic call. I will do a g_idle_add call as part of the callback definition function. I think with MT making sure everything plays by the defined rules, threading shouldn't be that scary.

JRS · « **Reply #99 on:** May 20, 2015, 06:30:16 PM »

Charles,

I have been spending a lot of time lately learning from your DLLC code. You spent an amazing amount of time with Script BASIC and making it O2 accessible. If anyone needed an embeddable scripting engine for O2, you have it covered with SB.

Thanks for all the time, help and wealth of knowledge you have shared with me over the years.

John

JRS · « **Reply #100 on:** May 20, 2015, 09:17:14 PM »

Charles,

I noticed the HexToBin.sb program in the O2 zip and it dawned on me, was this the beginnings of an assembler?

Code: Script BASIC

 
 ' TEST HEXADECIMAL TO BINARY CONVERSION
 ' =====================================
 
 
  s="B8 04 03 02  01    c3"
 
  'CONVERT TO BINARY
  '-----------------
 
  le=len(s)
  i=1
  j=1
  a=0
  n=0
  while i<=le
    w=asc(mid(s,i,1))
    if w>96 then
      w-=39
    elseif w>64 then
      w-=7
    end if
    w-=48
    if w>=0 then
      a=a*16+w
      n=1
    else
      if n=1 then
        v[j]=chr(a)
        a=0
        j+=1
        n=0
      end if
    end if
    i+=1
  wend
  if n=1 then
    v[j]=chr(a)
  end if
 
 
  'SAVE BINARY
  '-----------
 
  op=join("",v)
 
  open "t.bin" for output as 1
  print #1,op
  close 1
 
  'LOAD BINARY
  '-----------
 
  n=filelen("t.bin")
  open "t.bin" for binary as 1
  op=input(n,1)
  close 1
  '
  'DISPLAY
  '-------
 
  print "lENGTH=" & len(op) & "  BYTE CONTENT="
 
  for i=1 to len(op)
    s="0" & hex(asc(mid(op,i,1)))
    print right(s,2) & " "
  next 
 
 
  line input z
 

JRS · « **Reply #101 on:** May 20, 2015, 10:58:46 PM »

Charles,

I think this is going to be easier than I thought. I'm able to run my IupLoopStepWait based callback from the host SB script and capture events in the thread. Once I get the TID (Thread ID) attached to the callback definition I'll give more than one thread a try. I'm thinking this is going to work for the first pass. It will make a good tutorial on threaded GUI.

JRS · « **Reply #102 on:** May 21, 2015, 08:01:06 PM »

For the most part I have this working. Before I move on to dealing with multiple threads I still need a sane callback map created by the threads but used by the host doing the calling. Most of this will be transparent in the second round when callbacks and calling SB scripts are handled internally in the extension module interface. Since my existing pre-thread IUP interface is close to working, it's worth extending the original hack to deal with threading.

So far it's been more fun than frustrating. Unlike the local variable type display issues I was having with the debugger.

Charles Pegge · « **Reply #103 on:** May 21, 2015, 11:31:48 PM »

Quote

I noticed the HexToBin.sb program in the O2 zip and it dawned on me, was this the beginnings of an assembler?

It is a seed program for something, but to become an X86 assembler, it needs another 150K!

Such is the dilemma of building demo programs - turning them into useful products is many times more complex.

JRS · « **Reply #104 on:** May 22, 2015, 07:54:24 PM »

I have made some progress with IUP running in a threaded mode. I still need to add the g_idle_add() to add thread support at the Gtk level.

iup.bas (callback functions)

Code: Script BASIC

FUNCTION MainLoop
LOCAL this_event, aname
  LoopStep()
  this_event = GetEvent()
  IF this_event <> undef THEN
    aname = GetActionName()
    IF this_event = event{this_event}[0] THEN
      ICALL(event{this_event}[1])
    END IF
  END IF
  MainLoop = aname
END FUNCTION
 
FUNCTION SetCallback(ih, aname, fname, pprog )
  event{ih}[0] = ih
  event{ih}[1] = fname
  event{ih}[2] = pprog
  SetCallback = __SetCallback(ih, aname)
END FUNCTION
 

iupmain.sb

Code: Script BASIC

IMPORT mt.bas
IMPORT sbt.inc
IMPORT iup.bas
 
SUB SB_Wait(mtvar)
  WHILE mt::GetVariable(mtvar) <> "OK"
    SB_msSleep(20)
  WEND
END SUB
 
sb1 = SB_ThreadStart("rqdemo1.sb",undef,"/etc/scriba/basic.conf")
SB_Wait("sb1_loaded")
 
sb1_rtn = SB_CallSubArgs(sb1, "main::main", sb1)
SB_Wait("sb1_main")
 
sb2 = SB_ThreadStart("rqdemo2.sb",undef,"/etc/scriba/basic.conf")
SB_Wait("sb2_loaded")
 
sb2_rtn = SB_CallSubArgs(sb2, "main::main", sb2)
SB_Wait("sb2_main")
 
threads = 2
sb1_active = TRUE
sb2_active = TRUE
 
WHILE threads
  IF sb1_active THEN
    sb1_event_class = SB_CallSubArgs(sb1, "iup::mainloop")
    IF sb1_event_class = "CLOSE_CB" THEN
      sb1_active = FALSE
      threads -= 1
    END IF
  END IF
  IF sb2_active THEN
    sb2_event_class = SB_CallSubArgs(sb2, "iup::mainloop")
    IF sb2_event_class = "CLOSE_CB" THEN
      sb2_active = FALSE
      threads -= 1
    END IF
  END IF
WEND
 
Iup::Close()
 

rqdemo1.sb (rqdemo2.sb is identical other than references as being the second thread)

Code: Script BASIC

' Script BASIC Rapid-Q form conversion
 
IMPORT mt.bas
IMPORT sbt.inc
IMPORT iup.bas
 
' CALLBACKS FUNCTIONS
 
SUB button_quit
  PRINT "Thread 1 Quit Button Pressed\n"
END SUB  
 
SUB win_exit
  ' Good-Bye   
END SUB
 
FUNCTION main(pProg)
 
  ' SBIUP-Q INIT
  
  Iup::Open()
  Iup::SetGlobal("DEFAULTFONT", "Sans, 7.5")
  
  ' CREATE FORM
  
  Form = Iup::Create("dialog")
         Iup::SetAttributes(Form, "RASTERSIZE=320x240, TITLE=\"Thread 1\"")
  
       Label1  = Iup::Create("label")
                 Iup::SetAttributes(Label1, "TITLE=\"Customer\", RASTERSIZE=55x13, FLOATING=YES, POSITION=\"19,19\"")
  
       Edit1   = Iup::Create("text")
                 Iup::SetAttributes(Edit1, "RASTERSIZE=121x21, FLOATING=YES, POSITION=\"72,16\"")
  
       Button1 = Iup::Create("button")
                 Iup::SetAttributes(Button1, "TITLE=\"&Quit\", RASTERSIZE=75x25, FLOATING=YES, POSITION=\"107,164\"")
  
  vbx = Iup::Vbox(Label1, Edit1, Button1)
  Iup::Append(Form, vbx)
                 
  ' SET CALLBACKS
  
  Iup::SetCallback(Form, "CLOSE_CB", ADDRESS(win_exit()))
  Iup::SetCallback(Button1, "ACTION", ADDRESS(button_quit()))
  Iup::Show(Form)
  mt::SetVariable("sb1_main","OK")
END FUNCTION
mt::SetVariable("sb1_loaded","OK")
 

.

Oxygen Basic

News:

Author Topic: SBT (Read 35397 times)

Charles Pegge

Re: SBT

JRS

Re: SBT

JRS

Re: SBT

JRS

Re: SBT

JRS

Re: SBT

Charles Pegge

Re: SBT

JRS

Re: SBT

JRS

Re: SBT

JRS

Re: SBT

JRS

Re: SBT

JRS

Re: SBT

JRS

Re: SBT

JRS

Re: SBT

Charles Pegge

Re: SBT

JRS

Re: SBT