Author Topic: COM OLE (Read 3671 times)

JRS · « **Reply #15 on:** March 18, 2021, 07:09:06 PM »

I gave this a try but the CallByName never returns an osession value. I do get past the first CallByName call.

Code: OxygenBasic

' O2 Sage BOI
 
$filename "t.exe"                                    
uses  COM/COMutil                                    
CoInitialize null
 
sys osession                                    
CreateInterfaceByName "ProvideX.Script" oscript
CallByName(oscript, "Init", "C:\Sage\Sage 100 Standard\MAS90\Home")
osession = CallByName(oscript, "NewObject", "SY_Session")
print osession
 
oscript.Release                                        
CoUninitialize 
 

JRS · « **Reply #16 on:** March 20, 2021, 09:42:13 AM »

Charles,

It looks the O2 COM/OLE API only supports passing strings. Longs / integers or iDispatch pointers aren't there yet. Are my assumptions correct?

Charles Pegge · « **Reply #17 on:** March 21, 2021, 03:47:07 AM »

Hi John,

I think this will deliver objects:

Code: [Select]

'09:33 21/03/2021
' O2 Sage BOI
 
$filename "t.exe"                                    
uses  COM/COMutil

function CallByNameSV(IDispatch *vi, word flag, BSTR name, BSTR *sa=null, int c=0, VARIANT *vr=null) as int
===========================================================================================================
  int i
  VARIANT va[8] 'up to 8 params
  indexbase 1
  '
  for i=1 to c
   va[i].vt=VT_BSTR
   ?va[i].bstrVal=?sa[i] 'direct coupling
  next
  '
  err=CallByNameV(vi, flag, name, va, c, vr) 'VARIANT morph
  '
  for i=1 to c
    frees sa[i]
  next
  return err
end function

macro ObjectByName(vi,fl,nf,sa,sr,   rv)
========================================
  idispatch *sr
  VARIANT rv
  CallByNameSV(vi, fl, nf, sa, countof, rv)
  @sr=@rv.ppdispVal
end macro


CoInitialize null
 
CreateInterfaceByName "ProvideX.Script" oscript
CallByName(oscript, "Init", BSTR {"C:\Sage\Sage 100 Standard\MAS90\Home"})

'SB>>
'osession = COM::CBN(oscript, "NewObject", :SET, "SY_Session")

'longhand:
'idispatch *osession
'VARIANT rv
'CallByNameSV(oscript, SET, "NewObject", BSTR {"SY_Session"}, countof, rv)
'@osession=@rv.ppdispVal

ObjectByName(oscript, SET, "NewObject", BSTR {"SY_Session"},osession)

print @osession 'check pointer
 
oscript.Release                                        
CoUninitialize

JRS · « **Reply #18 on:** March 21, 2021, 08:49:24 AM »

Thanks Charles!

I'll give this a try. How would I pass int/long arguments?

JRS · « **Reply #19 on:** March 21, 2021, 09:31:50 AM »

Here is my attempt to get an object pointer.

Adding int SET = 8 causes the print of osession to be zero. (no errors)

Code: OxygenBasic

' O2 Sage BOI
 
$filename "t.exe"                                    
uses  COM/COMutil                                    
 
function CallByNameSV(IDispatch *vi, word flag, BSTR name, BSTR *sa=null, int c=0, VARIANT *vr=null) as int
===========================================================================================================
  int i
  VARIANT va[8] 'up to 8 params
  indexbase 1
  '
  for i=1 to c
   va[i].vt=VT_BSTR
   ?va[i].bstrVal=?sa[i] 'direct coupling
  next
  '
  err=CallByNameV(vi, flag, name, va, c, vr) 'VARIANT morph
  '
  for i=1 to c
    frees sa[i]
  next
  return err
end function
 
macro ObjectByName(vi,fl,nf,sa,sr,   rv)
========================================
  idispatch *sr
  VARIANT rv
  CallByNameSV(vi, fl, nf, sa, countof, rv)
  @sr=@rv.ppdispVal
end macro
 
 
CoInitialize null
 
CreateInterfaceByName "ProvideX.Script" oscript
CallByName(oscript, "Init", BSTR {"C:\Sage\Sage 100 Standard\MAS90\Home"})
 
ObjectByName(oscript, SET, "NewObject", BSTR {"SY_Session"},osession)
 
print @osession 'check pointer
 
oscript.Release                                       
CoUninitialize
 

Here is my Excel SB example so you can try these COM/OLE requirements on your box.

JRS · « **Reply #20 on:** March 21, 2021, 03:39:56 PM »

Here is the firstcust.sb example using the SB COM debug DLL. Maybe this will be of help. It would be nice if I could define iDispatch arguments pointers as follows.

DISP {osession}

All returns to O2 should be either standard strings, longs or floats.

Code: Script BASIC

' Sage BOI (Business Object Interface)- first customer - selected columns
 
IMPORT COM.sbi
 
oscript = COM::CREATE(:SET, "ProvideX.Script")
COM::CBN oScript, "Init", :CALL, "C:\\Sage\\Sage 100 Standard\\MAS90\\Home"
osession = COM::CBN(oscript, "NewObject", :SET, "SY_Session")
COM::CBN osession, "nSetUser", :CALL, "js", "northstar"
COM::CBN osession, "nsetcompany", :CALL, "ABC"
COM::CBN osession, "nSetDate", :CALL, "A/R", "20171218"
COM::CBN osession, "nSetModule", :CALL, "A/R"
ocust = COM::CBN(oscript, "NewObject", :SET, "AR_Customer_svc", osession)
COM::CBN ocust, "nMoveFirst"
CustomerNo$ = COM::CBN(ocust, "sCustomerNo", :GET)
CustomerName$ = COM::CBN(ocust, "sCustomerName", :GET)
City$ = COM::CBN(ocust, "sCity", :GET)
State$ = COM::CBN(ocust, "sState", :GET)
TelephoneNo$ = COM::CBN(ocust, "sTelephoneNo", :GET)
COM::CBN ocust, "DropObject"
COM::CBN osession, "DropObject"
COM::RELEASE oscript
 
PRINT "Customer:  ", CustomerNo$, "  ", CustomerName$, "  ", City$, "  ", State$, "  ", TelephoneNo$, "\n"
 

Code: Text

C:\ScriptBASIC\sage>sbc firstcust.sb
 
CreateObject 2 args
CreateObject(:SET, ProvideX.Script)
ProvideX.Script seems to return d!&#8595;w&#9786;valid IDISPATCH pointer
 
CallByName 4 args
CallByName(obj=a00fcc, method='Init', calltype=1 , comArgs=1)
VTYPE_STRING: C:\Sage\Sage 100 Standard\MAS90\Home (iter=0)
VT_EMPTY returned : return value from COM function was empty
 
CallByName 4 args
CallByName(obj=a00fcc, method='NewObject', calltype=8 , comArgs=1)
VTYPE_STRING/IDISPATCH: SY_Session (iter=0)
VT_DISPATCH returned : return value from COM function was integer: a00f84
 
CallByName 5 args
CallByName(obj=a00f84, method='nSetUser', calltype=1 , comArgs=2)
VTYPE_STRING: northstar (iter=0)
VTYPE_STRING: js (iter=1)
VT_I4 returned : return value from COM function was integer: 1
 
CallByName 4 args
CallByName(obj=a00f84, method='nsetcompany', calltype=1 , comArgs=1)
VTYPE_STRING: ABC (iter=0)
VT_I4 returned : return value from COM function was integer: 1
 
CallByName 5 args
CallByName(obj=a00f84, method='nSetDate', calltype=1 , comArgs=2)
VTYPE_STRING: 20171218 (iter=0)
VTYPE_STRING: A/R (iter=1)
VT_I4 returned : return value from COM function was integer: 1
 
CallByName 4 args
CallByName(obj=a00f84, method='nSetModule', calltype=1 , comArgs=1)
VTYPE_STRING: A/R (iter=0)
VT_I4 returned : return value from COM function was integer: 1
 
CallByName 5 args
CallByName(obj=a00fcc, method='NewObject', calltype=8 , comArgs=2)
FROM BYREF => VTYPE_LONG/IDISPATCH: a00f84 is valid pointer
VTYPE_STRING: AR_Customer_svc (iter=1)
VT_DISPATCH returned : return value from COM function was integer: a011c4
 
CallByName 2 args
CallByName(obj=a011c4, method='nMoveFirst', calltype=1 , comArgs=0)
VT_I4 returned : return value from COM function was integer: 1
 
CallByName 3 args
CallByName(obj=a011c4, method='sCustomerNo', calltype=2 , comArgs=0)
VT_BSTR returned : return value from COM function was string: ABF
 
CallByName 3 args
CallByName(obj=a011c4, method='sCustomerName', calltype=2 , comArgs=0)
VT_BSTR returned : return value from COM function was string: American Business Futures
 
CallByName 3 args
CallByName(obj=a011c4, method='sCity', calltype=2 , comArgs=0)
VT_BSTR returned : return value from COM function was string: Milwaukee
 
CallByName 3 args
CallByName(obj=a011c4, method='sState', calltype=2 , comArgs=0)
VT_BSTR returned : return value from COM function was string: WI
 
CallByName 3 args
CallByName(obj=a011c4, method='sTelephoneNo', calltype=2 , comArgs=0)
VT_BSTR returned : return value from COM function was string: (414) 555-4787
 
CallByName 2 args
CallByName(obj=a011c4, method='DropObject', calltype=1 , comArgs=0)
VT_EMPTY returned : return value from COM function was empty
 
CallByName 2 args
CallByName(obj=a00f84, method='DropObject', calltype=1 , comArgs=0)
VT_EMPTY returned : return value from COM function was empty
Customer:  ABF  American Business Futures  Milwaukee  WI  (414) 555-4787
 
C:\ScriptBASIC\sage>
 

Charles Pegge · « **Reply #21 on:** March 21, 2021, 04:58:18 PM »

I need to know how SET is implemented in gory detail. Do you have the source code for your BOI module?

JRS · « **Reply #22 on:** March 21, 2021, 06:21:50 PM »

Here is an Excel example before Mike (miss him a lot!) added the ability to pass iDispatch argument pointers to the SB COM interface.

Code: Script BASIC

IMPORT COM.sbi
 
filename = "C:\\ScriptBASIC\\examples\\warehouse.xls"
 
IF FileExists(filename) THEN
  PRINT "File already exists deleting: ", filename,"\n"
  DELETE filename
END IF
 
oExcelApp = COM::CREATE(:SET, "Excel.Application")
 
IF oExcelApp = 0 THEN
  PRINT "Failed to create Excel Object do you have it installed?\n"
  END
END IF 
 
' VBS: Set ExcelWorkbook = ExcelApp.Workbooks.Add
oWorkBook = COM::CBN(oExcelApp, "Workbooks", :GET)
 
IF oWorkBook = 0 THEN 
  PRINT "Failed to create Workbook\n"
  END
END IF 
 
oExcelWorkbook = COM::CBN(oWorkBook, "Add")
 
' VBS: Set ExcelSheet = ExcelWorkbook.Worksheets(1)
oExcelSheet = COM::CBN(oExcelWorkbook, "Worksheets", :GET, 1)
 
IF oExcelSheet = 0 THEN 
  PRINT "Failed to get oExcelSheet\n"
  END
END IF
 
' Adding cells...
 
oRange =  COM::CBN(oExcelSheet, "Range", :GET, "G3")
 
IF oRange = 0 THEN 
  PRINT "Failed to get oRange\n"
  END
END IF
 
COM::CBN(oRange, "Value", :LET, "123")
COM::RELEASE(oRange)
 
oRange =  COM::CBN(oExcelSheet, "Range", :GET, "B1:B5")
 
IF oRange = 0 THEN 
  PRINT "Failed to get oRange\n"
  END
END IF 
 
' Place BOLD border around range
CONST XlBorderWeight_xlMedium = -4138
COM::CBN(oRange, "BorderAround", :CALL, 1, XlBorderWeight_xlMedium, 3)
 
oInterior = COM::CBN(oRange, "Interior", :GET)
 
IF oInterior = 0 THEN 
  PRINT "Failed to get oInterior\n"
  END
END IF  
 
COM::CBN(oInterior, "ColorIndex", :LET, "38")
COM::CBN(oInterior, "Pattern", :LET, "xlSolid")
 
COM::RELEASE(oRange)
COM::RELEASE(oInterior)
 
FOR i=1 TO 10
  FOR j=1 TO 10
'   VBS: ExcelSheet.Cells(i, j).Value = "test-" & i & "-" & j
    oCell = COM::CBN(oExcelSheet, "Cells", :GET, i, j)
    COM::CBN(oCell, "Value", :LET, "test-" & i & "-" & j)
    COM::RELEASE(oCell)
  NEXT
NEXT
 
' Saving spreadsheet 
COM::CBN(oExcelWorkbook, "SaveAs", :CALL, filename)
COM::CBN(oExcelWorkbook, "Close")
COM::CBN(oExcelApp, "Quit")
 
' Releasing objects from memory
COM::RELEASE(oExcelSheet)
COM::RELEASE(oExcelWorkbook)
COM::RELEASE(oWorkBook)
COM::RELEASE(oExcelApp)
 

COM.sbi

Code: Script BASIC

GLOBAL CONST :CALL   = 1
GLOBAL CONST :GET    = 2
GLOBAL CONST :LET    = 4
GLOBAL CONST :SET    = 8
 
MODULE COM
 
DECLARE SUB ::CREATE  ALIAS "CreateObject"      LIB "com"
DECLARE SUB ::CBN     ALIAS "CallByName"        LIB "com"
DECLARE SUB ::RELEASE ALIAS "ReleaseObject"     LIB "com"
DECLARE SUB ::GHO     ALIAS "GetHostObject"     LIB "com"
DECLARE SUB ::GHS     ALIAS "GetHostString"     LIB "com"
DECLARE SUB ::TN      ALIAS "TypeName"          LIB "com"
DECLARE SUB ::DI      ALIAS "DescribeInterface" LIB "com"
DECLARE SUB ::CB      ALIAS "SBCallBack"        LIB "com"
 
END MODULE
 

Attached is the ScriptBasic COM module C source. Mike made the the changes (:SET and passing iDispatch pointers) to the CallByName function.

Charles Pegge · « **Reply #23 on:** March 22, 2021, 07:21:41 AM »

What happens when you use METHOD/CALL which equals 1 instead of SET which equals 8 ?

Essentially, this is what happens inside your COM module with Mike's modifications.

PS You can use integer,, float and string arguments

PS I dont have Excel.

JRS · « **Reply #24 on:** March 22, 2021, 12:32:05 PM »

I'll give that a try.

Thanks for the reply!

JRS · « **Reply #25 on:** March 22, 2021, 12:43:12 PM »

That worked.

Code: Text

ObjectByName(oscript, METHOD, "NewObject", BSTR {"SY_Session"},osession)
 

Let me see if I can get the rest of the script going.

Bummer on no Excel.

Can I add the additional ObjectByName code to COM\util if this works?

JRS · « **Reply #26 on:** March 22, 2021, 05:56:35 PM »

Here is where I'm at.

Code: OxygenBasic

' O2 Sage BOI
 
$filename "t.exe"                                    
uses  COM/COMutil                                    
 
 
function CallByNameSV(IDispatch *vi, word flag, BSTR name, BSTR *sa=null, int c=0, VARIANT *vr=null) as int
===========================================================================================================
  int i
  VARIANT va[8] 'up to 8 params
  indexbase 1
  '
  for i=1 to c
   va[i].vt=VT_BSTR
   ?va[i].bstrVal=?sa[i] 'direct coupling
  next
  '
  err=CallByNameV(vi, flag, name, va, c, vr) 'VARIANT morph
  '
  for i=1 to c
    frees sa[i]
  next
  return err
end function
 
macro ObjectByName(vi,fl,nf,sa,sr,   rv)
========================================
  idispatch *sr
  VARIANT rv
  CallByNameSV(vi, fl, nf, sa, countof, rv)
  @sr=@rv.ppdispVal
end macro
 
 
CoInitialize null
 
CreateInterfaceByName "ProvideX.Script" oscript
CallByName(oscript, "Init", BSTR {"C:\Sage\Sage 100 Standard\MAS90\Home"})
 
ObjectByName(oscript, METHOD, "NewObject", BSTR {"SY_Session"},osession)
CallByName(osession, "nSetUser", BSTR {"js", "MY_PASSWORD"})
CallByName(osession, "nsetcompany", BSTR {"ABC"})
CallByName(osession, "nSetDate", BSTR {"A/R", "20210322"})
CallByName(osession, "nSetModule", BSTR {"A/R"})
ObjectByName(oscript, "NewObject", METHOD, BSTR {"AR_Customer_svc"}, osession, ocust)
CmdByName(ocust, "nMoveFirst")
GetByName(ocust, "sCustomerNo", customerno)
GetByName(ocust, "sCustomerName", customername)
GetByName(ocust, "sCity", city)
GetByName(ocust, "sState", state)
GetByName(ocust, "sTelephoneNo", telephoneno)
CmdByName(ocust, "DropObject")
CmdByName(osession, "DropObject")
 
' print @osession 'check pointer
 
print "Customer:  ", customerno, "  ", customername, "  ", city, "  ", state, "  ", telephoneno
 
oscript.Release                                       
CoUninitialize
 

JRS · « **Reply #27 on:** March 22, 2021, 08:28:21 PM »

Here my attempt at the Excel demo.

Code: OxygenBasic

' O2 Excel Example
 
$filename "exceldemo.exe"                                    
uses  COM/COMutil                                    
 
string filename
int i, j
 
filename = "C:\OxygenBasic\examples\COM\exceldemo.xls"
CreateInterfaceByName "Excel.Application" oExcelApp
GetByName(oExcelApp, "Workbooks", oWorkBook)
CallByName(oWorkBook, "Add", oExcelWorkbook)
GetByName(oExcelWorkbook, "Worksheets", 1, oExcelSheet)
GetByName(oExcelSheet, "Range", BSTR {"G3"}, oRange)
LetByName(oRange, "Value", BSTR {"123"})
oRange.Release 
GetByName(oExcelSheet, "Range", BSTR {"B1:B5"}, oRange)
CallByName(oRange, "BorderAround", 1, -4138, 3)
GetByName(oRange, "Interior", oInterior)
LetByName(oInterior, "ColorIndex", BSTR {"38"})
LetByName(oInterior, "Pattern", BSTR {"xlSolid"})
oRange.Release
oInterior.Release
for i = 0 to 10
  for j = 0 to 10
    GetByName(oExcelSheet, "Cells", i, j, oCell)
    LetByName(oCell, "Value", BSTR {"test-" + i + "-" + j})
    oCell.Release
  next j   
next i    
CallByName(oExcelWorkbook, "SaveAs", BSTR {filename})
CmdByName(oExcelWorkbook, "Close")
CmdByName(oExcelApp, "Quit")
oExcelSheet.Release
oExcelWorkbook.Release
oWorkBook.Release
oExcelApp.Release
 
print "Speadsheet Created."
 

JRS · « **Reply #28 on:** March 22, 2021, 10:04:18 PM »

This attempt used ObjectByName() to return object pointers SB returned with CALL and GET.

Code: OxygenBasic

' O2 Excel Example
 
$filename "exceldemo.exe"                                    
uses  COM/COMutil                                    
 
function CallByNameSV(IDispatch *vi, word flag, BSTR name, BSTR *sa=null, int c=0, VARIANT *vr=null) as int
===========================================================================================================
  int i
  VARIANT va[8] 'up to 8 params
  indexbase 1
  '
  for i=1 to c
   va[i].vt=VT_BSTR
   ?va[i].bstrVal=?sa[i] 'direct coupling
  next
  '
  err=CallByNameV(vi, flag, name, va, c, vr) 'VARIANT morph
  '
  for i=1 to c
    frees sa[i]
  next
  return err
end function
 
macro ObjectByName(vi,fl,nf,sa,sr,   rv)
========================================
  idispatch *sr
  VARIANT rv
  CallByNameSV(vi, fl, nf, sa, countof, rv)
  @sr=@rv.ppdispVal
end macro
 
 
string filename
int i, j
 
filename = "C:\OxygenBasic\examples\COM\exceldemo.xls"
CreateInterfaceByName "Excel.Application" oExcelApp
ObjectByName(oExcelApp, METHOD, "Workbooks", oWorkBook)
ObjectByName(oWorkBook, METHOD, "Add", oExcelWorkbook)
ObjectByName(oExcelWorkbook, METHOD, "Worksheets", 1, oExcelSheet)
ObjectByName(oExcelSheet, METHOD, "Range", BSTR {"G3"}, oRange)
LetByName(oRange, "Value", BSTR {"123"})
oRange.Release 
ObjectByName(oExcelSheet, METHOD, "Range", BSTR {"B1:B5"}, oRange)
CallByName(oRange, "BorderAround", 1, -4138, 3)
ObjectByName(oRange, METHOD, "Interior", oInterior)
LetByName(oInterior, "ColorIndex", BSTR {"38"})
LetByName(oInterior, "Pattern", BSTR {"xlSolid"})
oRange.Release
oInterior.Release
for i = 0 to 10
  for j = 0 to 10
    ObjectByName(oExcelSheet, METHOD, "Cells", i, j, oCell)
    LetByName(oCell, "Value", BSTR {"test-" + str(i) + "-" + str(j)})
    oCell.Release
  next j   
next i    
CallByName(oExcelWorkbook, "SaveAs", BSTR {filename})
CmdByName(oExcelWorkbook, "Close")
CmdByName(oExcelApp, "Quit")
oExcelSheet.Release
oExcelWorkbook.Release
oWorkBook.Release
oExcelApp.Release
 
print "Speadsheet Created."
 

Charles Pegge · « **Reply #29 on:** March 23, 2021, 10:08:35 AM »

Hi John,

Latest ComUtil with simplified ObjectByName

Code: [Select]

'07:01 23/03/2021
$filename "exceldemo.exe"
'uses RTL32                                    
uses  COM/COMutil                                    
 
 
string filename
int i, j
 
filename = "C:\OxygenBasic\examples\COM\exceldemo.xls"
CreateInterfaceByName "Excel.Application" oExcelApp
ObjectByName(oExcelApp, "Workbooks", BSTR {}, oWorkBook)
ObjectByName(oWorkBook, "Add", BSTR {0}, oExcelWorkbook)
ObjectByName(oExcelWorkbook, "Worksheets", BSTR {1}, oExcelSheet)
ObjectByName(oExcelSheet, "Range", BSTR {"G3"}, oRange)
LetByName(oRange, "Value", 123)
oRange.Release 
ObjectByName(oExcelSheet, "Range", BSTR {"B1:B5"}, oRange)
CallByName(oRange, "BorderAround", BSTR {1, -4138, 3})
ObjectByName(oRange, "Interior", BSTR {1}, oInterior)
LetByName(oInterior, "ColorIndex", 38)
LetByName(oInterior, "Pattern", "xlSolid")
oRange.Release
oInterior.Release
for i = 0 to 10
  for j = 0 to 10
    ObjectByName(oExcelSheet, "Cells", BSTR {i, j}, oCell)
    LetByName(oCell, "Value", "test-" + str(i) + "-" + str(j))
    oCell.Release
  next j   
next i    
CallByName(oExcelWorkbook, "SaveAs", BSTR {filename})
CmdByName(oExcelWorkbook, "Close")
CmdByName(oExcelApp, "Quit")
oExcelSheet.Release
oExcelWorkbook.Release
oWorkBook.Release
oExcelApp.Release
 
print "Speadsheet Created."

Oxygen Basic

News:

Author Topic: COM OLE (Read 3671 times)

JRS

Re: COM OLE

JRS

Re: COM OLE

Charles Pegge

Re: COM OLE

JRS

Re: COM OLE

JRS

Re: COM OLE

JRS

Re: COM OLE

Charles Pegge

Re: COM OLE

JRS

Re: COM OLE

Charles Pegge

Re: COM OLE

JRS

Re: COM OLE

JRS

Re: COM OLE

JRS

Re: COM OLE

JRS

Re: COM OLE

JRS

Re: COM OLE

Charles Pegge

Re: COM OLE